# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop xdg

MY_PN="metrolist"
DESCRIPTION="YouTube Music client for desktop"
HOMEPAGE="https://metrolist.cc/ https://github.com/MetrolistGroup/Metrolist/"
SRC_URI="
	amd64? ( https://github.com/MetrolistGroup/Metrolist/releases/download/v${PV}/${MY_PN}-desktop-linux-x64-${PV}.AppImage )
	arm64? ( https://github.com/MetrolistGroup/Metrolist/releases/download/v${PV}/${MY_PN}-desktop-linux-arm64-${PV}.AppImage )
"
S="${WORKDIR}/squashfs-root"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 arm64"
IUSE="+login"

RESTRICT="strip"

RDEPEND="
	login? ( net-libs/webkit-gtk:4.1 )
"

QA_PREBUILT="opt/${MY_PN}/*"

src_unpack() {
	local appimage
	if use amd64; then
		appimage="${DISTDIR}/${MY_PN}-desktop-linux-x64-${PV}.AppImage"
	elif use arm64; then
		appimage="${DISTDIR}/${MY_PN}-desktop-linux-arm64-${PV}.AppImage"
	fi

	cp "${appimage}" "${WORKDIR}/metrolist.AppImage" || die
	chmod +x "${WORKDIR}/metrolist.AppImage" || die

	"${WORKDIR}/metrolist.AppImage" --appimage-extract >/dev/null || die
}

src_install() {
	insinto "/opt/${MY_PN}"
	doins -r .

	fperms +x "/opt/${MY_PN}/AppRun" "/opt/${MY_PN}/bin/Metrolist" "/opt/${MY_PN}/bin/Metrolist.bin"

	dosym "/opt/${MY_PN}/bin/Metrolist" "/usr/bin/${MY_PN}"

	newicon "lib/Metrolist.png" "${MY_PN}.png"
	make_desktop_entry "${MY_PN}" "Metrolist" "${MY_PN}" "AudioVideo;Audio;Player;"
}