# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PACKAGING_COMMIT="2b3b38b5c08e5caf9f7ee75231e734856bc61cae"
inherit lomiri

KEYWORDS="~amd64"
SRC_URI="https://releases.ayatana-indicators.org/source/${PN}/${P}.tar.gz
         ${LOMIRI_PACKAGING_URI}"


DESCRIPTION="Ayatana Indicator Date & Time Applet"
HOMEPAGE="https://github.com/AyatanaIndicators/${PN}"
LICENSE="GPL-3"
SLOT="0"
IUSE="+lomiri"
RESTRICT="test mirror"

DEPEND="
    ayatana-indicators/ayatana-indicator-messages
    dev-cpp/properties-cpp
    dev-libs/libical
    dev-libs/glib
    gnome-extra/evolution-data-server
    media-libs/gstreamer
    net-libs/libaccounts-glib
    gui-libs/libayatana-common
    x11-libs/libnotify
    lomiri? (
        lomiri-base/lomiri-schemas
        lomiri-base/lomiri-url-dispatcher
        lomiri-extra/lomiri-sounds
    )
"

RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
"

src_configure() {
    local mycmakeargs=(
        -DENABLE_TESTS="OFF"
        -DENABLE_COVERAGE="OFF"
        -DENABLE_WERROR="ON"
        -DENABLE_LOMIRI_FEATURES="OFF"
    )
    lomiri_src_configure

    if use lomiri; then
        mycmakeargs=(
            -DENABLE_TESTS="OFF"
            -DENABLE_COVERAGE="OFF"
            -DENABLE_WERROR="ON"
            -DENABLE_LOMIRI_FEATURES="ON"
        )
        BUILD_DIR="${WORKDIR}/${P}_lomiri" lomiri_src_configure
    fi
}

src_compile() {
    cmake_src_compile
    if use lomiri; then
        BUILD_DIR="${WORKDIR}/${P}_lomiri" cmake_src_compile
    fi
}

src_install() {
    lomiri_src_install
    if use lomiri; then
        BUILD_DIR="${WORKDIR}/${P}_lomiri" cmake_src_install
        lomiri_prune_linguas
    fi

    local lomiri_variant=ayatana-indicator-datetime
    use lomiri && lomiri_variant=lomiri-indicator-datetime

    # create 'service,wants' symlinks
    dosym /usr/lib/systemd/user/${lomiri_variant}.service \
        /usr/lib/systemd/user/lomiri-indicators.target.wants/${lomiri_variant}.service
    dosym /usr/lib/systemd/user/ayatana-indicator-datetime.service \
        /usr/lib/systemd/user/ayatana-indicators.target.wants/ayatana-indicator-datetime.service
}