# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PACKAGING_COMMIT="406a4ec32f468e327e807df965d73e5e4a644163"
CMAKE_CHECK_ADDITIONAL_FILES=(
    examples/CMakeLists.txt
)
inherit lomiri multibuild

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://github.com/AyatanaIndicators/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://github.com/AyatanaIndicators/${PN}/archive/${PV}/${PN}-${PV}.tar.gz
            ${LOMIRI_PACKAGING_URI}"
fi

DESCRIPTION="Qt renderer for Ayatana Indicators"
HOMEPAGE="https://github.com/AyatanaIndicators/${PN}"

LICENSE="LGPL-3"
SLOT="0"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"
RESTRICT="test mirror"

DEPEND="
    dev-libs/glib:2
    qt5? (
        dev-qt/qtcore:5
        dev-qt/qtdeclarative:5
        dev-qt/qtgui:5
    )
    qt6? (
        dev-qt/qtbase:6[gui]
        dev-qt/qtdeclarative:6
    )
"

RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    virtual/pkgconfig
"

_set_multibuild_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _set_multibuild_variants

    qmenumodel_configure() {
        local mycmakeargs=(
            -DENABLE_COVERAGE="OFF"
            -DENABLE_TESTS="OFF"
            -DGENERATE_DOC="OFF"
        )

        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            mycmakeargs+=( -DENABLE_QT6="ON" )
        else
            mycmakeargs+=( -DENABLE_QT6="OFF" )
        fi

        cmake_src_configure
    }
    multibuild_foreach_variant qmenumodel_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _set_multibuild_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _set_multibuild_variants
    multibuild_foreach_variant lomiri_src_install
}