# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PACKAGING_COMMIT="1da8ffa220a065e0f9f7bfe334cdcc2854a93dbc"
inherit lomiri multibuild

SRC_URI="https://github.com/maliit/framework/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
         ${LOMIRI_PACKAGING_URI}"

DESCRIPTION="Maliit Input Method Framework."
HOMEPAGE="https://github.com/maliit/framework"
KEYWORDS="~amd64"
LICENSE="LGPL-2"
SLOT="0"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"
RESTRICT="mirror test"

COMMON_DEPEND="
    dev-libs/glib
    dev-libs/wayland
    sys-apps/dbus
    virtual/libudev
    x11-libs/libxcb
    x11-libs/libxkbcommon
    qt5? (
        dev-qt/qtcore:5
        dev-qt/qtdbus:5
        dev-qt/qtdeclarative:5
        dev-qt/qtgui:5
        dev-qt/qtwayland:5
    )
    qt6? (
        dev-qt/qtbase:6[dbus,gui]
        dev-qt/qtdeclarative:6
        dev-qt/qtwayland:6
    )
"
DEPEND="
    ${COMMON_DEPEND}
    dev-libs/wayland-protocols
"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    virtual/pkgconfig
    qt5? ( dev-qt/qtwaylandscanner:5 )
    qt6? ( dev-qt/qtwayland:6 )
"

S="${WORKDIR}/framework-${PV}"

_maliit_framework_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _maliit_framework_variants

    maliit_framework_configure() {
        local mycmakeargs=(
            -Denable-docs="OFF"       #TODO
            -Denable-tests="OFF"      #TODO
            -Dinstall-tests="OFF"
            -Denable-examples="OFF"
            -Denable-dbus-activation="ON"
        )

        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            mycmakeargs+=(
                -DBUILD_WITH_QT6="ON"
                -Denable-glib="OFF"
            )
        else
            mycmakeargs+=( -DBUILD_WITH_QT6="OFF" )
        fi

        lomiri_src_configure
    }
    multibuild_foreach_variant maliit_framework_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _maliit_framework_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _maliit_framework_variants
    multibuild_foreach_variant lomiri_src_install

    rm -r "${ED}"/usr/share/doc/maliit*-framework || die

    # maliit-server is started by lomiri-keyboard.service
    rm "${ED}"/usr/share/dbus-1/services/org.maliit.server.service || die
}