# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="26.6.19-1"
inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz
             ${LOMIRI_PPA_URI}"
fi

DESCRIPTION="Lomiri Indicator for controlling the location service"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    dev-cpp/properties-cpp
    dev-libs/glib:2
    lomiri-base/lomiri-app-launch
    lomiri-base/lomiri-url-dispatcher
"
RDEPEND="
    ${DEPEND}
    lomiri-base/lomiri-location-service
"

BDEPEND="
    dev-build/cmake
    dev-build/samurai
    sys-apps/systemd
    sys-devel/gettext
    virtual/pkgconfig
"

PATCHES=(
    "${FILESDIR}"/${PN}-cmake-post-build.patch
)

src_configure() {
    local mycmakeargs=(
        -Denable_tests=OFF
        -Denable_lcov=OFF
    )

    lomiri_src_configure
}

src_install() {
    lomiri_src_install

    dosym /usr/lib/systemd/user/${PN}.service \
        /usr/lib/systemd/user/lomiri-indicators.target.wants/${PN}.service
}