# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="1.2.0-4"
GUILE_COMPAT=( 2-2 3-0 )
inherit guile-single qmake-utils lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz
           ${LOMIRI_PPA_URI}"
fi

DESCRIPTION="Lomiri on-screen keyboard. Lomiri Keyboard based on Maliit-Keyboard"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-2"
SLOT="0"

DICT_L10N=(
    bg ca cs da de de-AT de-CH de-DE el en en-AU en-CA en-GB en-US en-ZA eo es fr he hr hu is it
    lt lv mk nb nl pl pt pt-BR ro ru sl sv tr uk
)

IUSE="+qt6 ${DICT_L10N[*]/#/l10n_}"
RESTRICT="test mirror"
REQUIRED_USE="${GUILE_REQUIRED_USE}"

COMMON_DEPEND="
    app-i18n/anthy
    app-i18n/libchewing
    app-i18n/libpinyin
    app-text/hunspell
    dev-libs/libpresage
    qt6? (
        dev-qt/qt5compat:6
        dev-qt/qtbase:6[dbus,gui,widgets]
        dev-qt/qtdeclarative:6
        gui-libs/maliit-framework[qt6]
        lomiri-base/gsettings-qt[qt6]
    )
    !qt6? (
        dev-qt/qtgui:5
        gui-libs/maliit-framework[qt5]
        lomiri-base/gsettings-qt[qt5]
        lomiri-extra/lomiri-ui-extras[qt5]
    )
"
DEPEND="${COMMON_DEPEND}"
RDEPEND="
    ${COMMON_DEPEND}
    media-fonts/noto-emoji
    qt6? (
        dev-libs/ktactilefeedback
        dev-qt/qtmultimedia:6[qml]
        lomiri-base/lomiri-ui-toolkit:6
    )
"
for lang in "${DICT_L10N[@]}"; do
    case ${lang} in
        pt-BR) dict=pt-br ;;
        *) dict=${lang%%-*} ;;
    esac
    RDEPEND+=" l10n_${lang}? ( app-dicts/myspell-${dict} )"
done
unset dict lang
BDEPEND="
    ${GUILE_DEPS}
    app-i18n/unicode-emoji
    sys-devel/autogen
    qt6? (
        dev-qt/qtshadertools:6
        sys-devel/gettext
    )
    !qt6? (
        dev-qt/qtdeclarative:5
        dev-util/intltool
    )
"

PATCHES=(
    "${FILESDIR}"/0001-qml5-use-Noto-Color-Emoji-font-for-the-emoji-plugin.patch
    "${FILESDIR}"/0002-ja-link-qt6-plugin-against-anthy.patch
    "${FILESDIR}"/0003-qml6-import-emoji-js-in-the-emoji-layout.patch
)

src_prepare() {
    if use qt6; then
        lomiri_src_prepare
    else
        lomiri_patch_debian_series

        sed -i "s|guile --no-auto-compile|${GUILE} --no-auto-compile|" src/plugin/plugin.pro || die
        sed -i "s|\$\${PREFIX}/lib/lomiri-keyboard|\$\${PREFIX}/$(get_libdir)/lomiri-keyboard|" config.pri || die
        sed -i "s|^ExecStart=maliit6-server|ExecStart=maliit-server|" \
            "${DEBIAN_PATCHES_S}"/debian/systemd/lomiri-keyboard.service || die

        default
    fi
}

src_configure() {
    if use qt6; then
        local mycmakeargs=(
            -DENABLE_DOCUMENTATION="OFF"
            -DENABLE_TESTS="OFF"
            -DGUILE_EXECUTABLE="${GUILE}"
        )
        lomiri_src_configure
    else
        eqmake5 CONFIG+="nodoc notests"
    fi
}

src_compile() {
    if use qt6; then
        cmake_src_compile
    else
        default
    fi
}

src_install() {
    if use qt6; then
        lomiri_src_install
    else
        emake install INSTALL_ROOT="${D}"
        lomiri_prune_linguas
    fi

    insinto /etc/xdg/maliit.org
    doins debian/server.conf

    sed -i '/^After=/a PartOf=graphical-session.target' \
        "${DEBIAN_PATCHES_S}"/debian/systemd/lomiri-keyboard.service || die
    insinto /usr/lib/systemd/user
    doins "${DEBIAN_PATCHES_S}"/debian/systemd/lomiri-keyboard.service
}