# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="1.5.0-3"
inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz
             ${LOMIRI_PPA_URI}"
fi

DESCRIPTION="System Settings application for Lomiri"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
IUSE="bluetooth geolocation wifi"
RESTRICT="test mirror"

DEPEND="
    ayatana-indicators/ayatana-indicator-datetime
    ayatana-indicators/ayatana-indicator-power
    dev-libs/glib
    gnome-base/gnome-desktop:4
    lomiri-base/gsettings-qt
    lomiri-base/lomiri-content-hub
    lomiri-base/lomiri-settings-components
    lomiri-base/lomiri-ui-toolkit:5
    lomiri-indicators/lomiri-indicator-network
    net-libs/geonames
    sys-apps/accountsservice
    sys-power/upower
"
RDEPEND="
    ${DEPEND}
    >=lomiri-base/lomiri-schemas-0.1.13
    lomiri-base/repowerd
    bluetooth? (
        ayatana-indicators/ayatana-indicator-bluetooth
        net-wireless/bluez
    )
    geolocation? ( lomiri-indicators/lomiri-indicator-location )
    wifi? (
        gui-libs/qmenumodel[qt5]
        net-misc/networkmanager[wifi]
    )
"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    dev-qt/qtconcurrent:5
    dev-qt/qtdeclarative:5
"

PATCHES=(
    "${FILESDIR}"/${PN}-optional-bluetooth.patch
    "${FILESDIR}"/${PN}-battery-charging-info-schema.patch
    "${FILESDIR}"/${PN}-bluetooth-authorization-signals.patch
)

src_prepare() {
    use bluetooth || cmake_comment_add_subdirectory -f plugins bluetooth
    use wifi || cmake_comment_add_subdirectory -f plugins wifi

    # disable not needed/working settings for now
    cmake_comment_add_subdirectory -f plugins example
    cmake_comment_add_subdirectory -f plugins flight-mode
    cmake_comment_add_subdirectory -f plugins gestures
    cmake_comment_add_subdirectory -f plugins hotspot
    cmake_comment_add_subdirectory -f plugins orientation-lock
    cmake_comment_add_subdirectory -f plugins vpn

    lomiri_src_prepare
}

src_configure() {
    local mycmakeargs=(
        -DENABLE_TESTS="OFF"
        -DENABLE_UBUNTU_ACCOUNTSSERVICE="OFF"
        #-DENABLE_LIBDEVICEINFO="ON" # -> use flag
    )

    cmake_src_configure
}