# Copyright 2025-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

CHROMIUM_LANGS="af am ar as az be bg bn bs ca cs cy da de el en-GB es es-419 et eu fa fi fil
	fr fr-CA gl gu he hi hr hu hy id is it ja ka kk km kn ko ky lo lt lv mk ml mn mr ms my
	nb ne nl or pa pl pt-BR pt-PT ro ru si sk sl sq sr sr-Latn sv sw ta te th tr uk ur uz
	vi zh-CN zh-HK zh-TW zu"

inherit chromium-2 desktop pax-utils xdg

DESCRIPTION="Private, fast, and honest web browser based on Chromium"
HOMEPAGE="https://helium.computer/"

MY_PN="ungoogled-chromium"
MY_P="${MY_PN}-${PV}"

SRC_URI="https://github.com/ungoogled-software/${MY_PN}-portablelinux/releases/download/${PV}-1/${MY_P}-1-x86_64_linux.tar.xz -> ${P}.tar.xz"

S=${WORKDIR}

LICENSE="GPL-3 BSD"
SLOT="0"
KEYWORDS="~amd64"

IUSE="qt6 selinux"

RESTRICT="bindist mirror"

RDEPEND="
	app-misc/ca-certificates
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	>=dev-libs/nss-3.26
	media-fonts/liberation-fonts
	media-libs/alsa-lib
	media-libs/mesa[gbm(+)]
	net-misc/curl
	net-print/cups
	sys-apps/dbus
	sys-libs/glibc
	sys-libs/libcap
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	gui-libs/gtk:4
	x11-libs/libdrm
	>=x11-libs/libX11-1.5.0
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libxcb
	x11-libs/libxkbcommon
	x11-libs/libxshmfence
	x11-libs/pango
	x11-misc/xdg-utils
	qt6? ( dev-qt/qtbase:6[gui,widgets] )
	selinux? ( sec-policy/selinux-chromium )
"

QA_PREBUILT="*"

pkg_setup() {
	chromium_suid_sandbox_check_kernel_config
}

# Skip unpack, we're doing it during install
src_unpack() {
	:
}

src_install() {
	dodir "opt" || die
	cd "${ED}/opt/" || die

	# Not possible to unpack to target folder, so: unpack, then mv
	unpack "${P}.tar.xz"
	mv ${MY_P}-1-x86_64_linux ${MY_PN} || die

	cd "${MY_PN}" || die

	pushd locales
	chromium_remove_language_paks
	popd

	rm "libqt5_shim.so" || die
	if ! use qt6; then
		rm "libqt6_shim.so" || die
	fi

	newicon -s 48 "product_logo_48.png" ${MY_PN}.png
	domenu "${FILESDIR}/${MY_PN}.desktop"
	dobin "${FILESDIR}/${MY_PN}"

	pax-mark m "${MY_PN}"
}