# Copyright 2026 ReK2 - Chris F.N. <rek2@hispagatos.org>
# https://rek2.hispagatos.org
# Distributed under the terms of the GNU General Public License v3

EAPI=8

# Upstream Cargo.toml uses edition = "2024"
RUST_MIN_VER="1.85.0"
CRATES=""

inherit cargo git-r3 shell-completion

DESCRIPTION="A Taskwarrior Terminal User Interface"
HOMEPAGE="
	https://github.com/kdheepak/taskwarrior-tui
	https://kdheepak.com/taskwarrior-tui
"
EGIT_REPO_URI="https://github.com/kdheepak/taskwarrior-tui.git"

LICENSE="MIT"
# Dependent crate licenses
LICENSE+="
	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions Boost-1.0 BSD-2
	CC0-1.0 ISC LGPL-2.1+ MPL-2.0 Unicode-3.0 Unicode-DFS-2016
	Unlicense WTFPL-2 ZLIB
"
SLOT="0"
KEYWORDS=""

RDEPEND="app-misc/task"

QA_FLAGS_IGNORED="usr/bin/taskwarrior-tui"

src_unpack() {
	git-r3_src_unpack
	cargo_live_src_unpack
}

src_install() {
	cargo_src_install

	newbashcomp completions/taskwarrior-tui.bash taskwarrior-tui
	dofishcomp completions/taskwarrior-tui.fish
	newzshcomp completions/_taskwarrior-tui _taskwarrior-tui
	doman packaging/man/taskwarrior-tui.1

	einstalldocs
}