# Copyright 2020-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="A new generation, open-source graphics plugin for N64 emulators."
HOMEPAGE="https://github.com/gonetz/GLideN64"
SHA="020b6ab5de1f13d8e673c0a23529f1de1e507c9d"
SRC_URI="https://github.com/gonetz/GLideN64/archive/${SHA}.tar.gz -> ${P}-${SHA:0:7}.tar.gz"

S="${WORKDIR}/GLideN64-${SHA}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"

DEPEND="app-arch/zstd
	media-libs/freetype
	media-libs/libglvnd[X]
	media-libs/libpng:=
	virtual/zlib"
RDEPEND="${DEPEND}"
CMAKE_USE_DIR="${S}/src"
CMAKE_BUILD_TYPE=Release

src_prepare() {
	cmake_src_prepare
	rm -rf src/GLideNHQ/inc || die
	# app-arch/zstd ships pkg-config metadata but no CMake package config, and
	# installs only a shared library.
	sed -e 's/FIND_PACKAGE( ZSTD REQUIRED )/find_package(PkgConfig REQUIRED)\n    pkg_check_modules(ZSTD REQUIRED IMPORTED_TARGET libzstd)/' \
		-e 's/zstd::libzstd_static/PkgConfig::ZSTD/' \
		-i src/GLideNHQ/CMakeLists.txt || die
}

src_configure() {
	echo "#define PLUGIN_REVISION ${SHA}" > Revision.h
	echo "#define PLUGIN_REVISION_W L${SHA}" >> Revision.h
	local mycmakeargs=(
		-DCRC_OPT=ON
		-DVEC4_OPT=ON
		-DMUPENPLUSAPI=ON
		-DUSE_SYSTEM_LIBS=ON
	)
	cmake_src_configure
}

src_install() {
	insinto "/usr/$(get_libdir)/mupen64plus"
	doins "${BUILD_DIR}/plugin/Release/mupen64plus-video-GLideN64.so"
	einstalldocs
}