# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MAIN_PH=66bb69f500e33ac1ceb0ea1a15b65db367ee05d9
AUX_PH=cfa4833190e35d41d9a806449796e35799d650e3

inherit racket

DESCRIPTION="The SRFI-105-for-Racket Racket package"
HOMEPAGE="https://pkgs.racket-lang.org/package/SRFI-105-for-Racket"
SRC_URI="https://github.com/damien-mattei/SRFI-105-for-Racket/archive/${MAIN_PH}.tar.gz -> ${P}.tar.gz
	https://github.com/damien-mattei/Scheme-PLUS-for-Racket/archive/${AUX_PH}.tar.gz -> ${PN}_aux_Scheme-PLUS-for-Racket-${PV}.tar.gz"
S="${WORKDIR}/SRFI-105-for-Racket-${MAIN_PH}/"

LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

RDEPEND="dev-racket/scribble-code-examples"
BDEPEND="${RDEPEND}"
PDEPEND="dev-racket/scheme-plus-for-racket"

src_compile() {
	pushd "${WORKDIR}/Scheme-PLUS-for-Racket-${AUX_PH}/" >/dev/null || die
	raco_bare_install user Scheme-PLUS-for-Racket
	popd >/dev/null || die

	racket_src_compile
}

pkg_prerm() {
	if [[ -z "${REPLACED_BY_VERSION}" ]] && racket-where Scheme-PLUS-for-Racket ; then
		raco_remove "${RACKET_PN}" Scheme-PLUS-for-Racket
	fi
}

pkg_postinst() {
	! racket-where "${RACKET_PN}" && raco_system_install

	has_version dev-racket/scheme-plus-for-racket &&
		raco_system_setup "${RACKET_PN}" Scheme-PLUS-for-Racket
}