# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=9

COMPOSER_INSTALL_PATH="Composer/Spdx"

inherit composer git-r3

DESCRIPTION="Tools for working with and validating SPDX licenses"
HOMEPAGE="https://github.com/composer/spdx-licenses"
EGIT_REPO_URI="https://github.com/composer/spdx-licenses.git"

LICENSE="MIT"
SLOT="0"

RDEPEND="!dev-php/spdx-licenses"

PATCHES=( "${FILESDIR}/${PN}"-1.5.8-res-path.patch
	"${FILESDIR}/${PN}"-1.6.0-tests.patch )

EPHPUNIT_BOOTSTRAP='tmp/fake/src/autoload.php'
# exclude tests for non-existed class
EPHPUNIT_EXCLUDE_FILTER='testDump(Licenses|Exceptions)'
composer_enable_tests phpunit

src_prepare() {
	composer_src_prepare

	# mimic system path for bootstrap
	edo mkdir -p composer tmp/fake
	edo ln -s -t composer ../res
	# mimic system path for bootstrap
	edo cp -a src tests tmp/fake
}

src_test() {
	ephpunit tmp/fake/tests
}

src_install() {
	composer_src_install

	insinto /usr/share/composer/res
	doins -r res/.
}