# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri multibuild qmake-utils

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="The Lomiri-indicator-network service is responsible for exporting the system settings menu through dbus."
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="LGPL-3 GPL-3"
SLOT="0"
IUSE="+qt6"
RESTRICT="test mirror"

COMMON_DEPEND="
    app-crypt/libsecret
    dev-libs/glib
    lomiri-base/lomiri-api
    lomiri-base/lomiri-url-dispatcher
    net-misc/libqofono[qt5]
    net-misc/networkmanager
    net-misc/ofono
    dev-qt/qtcore:5
    dev-qt/qtdbus:5
    dev-qt/qtdeclarative:5
    qt6? (
        dev-qt/qtbase:6[dbus]
        dev-qt/qtdeclarative:6
    )
"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
    dev-build/cmake-extras
    sys-devel/gettext
"

src_prepare() {
    lomiri_src_prepare

    lomiri_qt_export_headers lomiri-connectivity-qt1 lomiri-connectivity-qt6 -- \
        $(grep -rlw Q_DECL_EXPORT src/connectivity-api/connectivity-qt --include='*.h')
}

_lomiri_indicator_network_variants() {
    MULTIBUILD_VARIANTS=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _lomiri_indicator_network_variants

    lomiri_indicator_network_configure() {
        local mycmakeargs=(
            -DENABLE_TESTS=OFF
            -DENABLE_COVERAGE=OFF
        )

        # the indicator service is Qt5-only, Qt6 provides the connectivity API
        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            local -x PATH="$(qt6_get_bindir):${PATH}"
            mycmakeargs+=(
                -DENABLE_QT6=ON
                -DBUILD_LIBCONNECTIVITY_ONLY=ON
            )
        else
            local -x PATH="$(qt5_get_bindir):${PATH}"
            mycmakeargs+=( -DENABLE_QT6=OFF )
        fi

        lomiri_src_configure
    }
    multibuild_foreach_variant lomiri_indicator_network_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _lomiri_indicator_network_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _lomiri_indicator_network_variants
    multibuild_foreach_variant lomiri_src_install

    dosym lomiri-indicator-network.service /usr/lib/systemd/user/dbus-com.lomiri.connectivity1.service
}