# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri multibuild qmake-utils

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION=" A collection of UI components that for various reasons can't be included in the main Lomiri UI toolkit."
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"
RESTRICT="test mirror"

COMMON_DEPEND="
    dev-libs/glib
    media-gfx/exiv2
    net-print/cups
    sys-libs/pam
    qt5? (
        dev-qt/qtconcurrent:5
        dev-qt/qtcore:5
        dev-qt/qtdbus:5
        dev-qt/qtdeclarative:5
        dev-qt/qtgui:5
        dev-qt/qtprintsupport:5
        dev-qt/qtwidgets:5
        dev-qt/qtxml:5
    )
    qt6? (
        dev-qt/qtbase:6[concurrent,dbus,gui,widgets,xml]
        dev-qt/qtdeclarative:6
    )
"
DEPEND="
    ${COMMON_DEPEND}
    qt5? ( dev-qt/qttest:5 )
"
RDEPEND="
    ${COMMON_DEPEND}
    qt5? ( lomiri-base/lomiri-ui-toolkit:5 )
    qt6? ( lomiri-base/lomiri-ui-toolkit:6 )
"
BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    sys-devel/gettext
    qt6? ( dev-qt/qtshadertools:6 )
"

PATCHES=(
    "${FILESDIR}"/002-remove-copy-files-for-qtcreator.patch
)

_lomiri_ui_extras_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _lomiri_ui_extras_variants

    lomiri_ui_extras_configure() {
        local mycmakeargs=(
            -DENABLE_TESTS="OFF"
            -DENABLE_WERROR="OFF"
        )

        # qmlplugindump is located via PATH
        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            local -x PATH="$(qt6_get_bindir):${PATH}"
            mycmakeargs+=( -DENABLE_QT6="ON" )
        else
            local -x PATH="$(qt5_get_bindir):${PATH}"
            mycmakeargs+=( -DENABLE_QT6="OFF" )
        fi

        lomiri_src_configure
    }
    multibuild_foreach_variant lomiri_ui_extras_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _lomiri_ui_extras_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _lomiri_ui_extras_variants
    multibuild_foreach_variant lomiri_src_install
}