# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri multibuild

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${PN}-${PV}.tar.gz"
fi

DESCRIPTION="An implementation of the Free Desktop Notification server for Lomiri"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"
RESTRICT="test mirror"

COMMON_DEPEND="
    qt5? (
        dev-qt/qtcore:5
        dev-qt/qtdbus:5
        dev-qt/qtdeclarative:5
        dev-qt/qtwidgets:5
    )
    qt6? (
        dev-qt/qtbase:6[dbus,widgets]
        dev-qt/qtdeclarative:6
    )
"
DEPEND="
    ${COMMON_DEPEND}
    lomiri-base/lomiri-api[qt5?,qt6?]
    qt5? ( dev-qt/qttest:5 )
"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
    dev-build/cmake-extras
    virtual/pkgconfig
"

_lomiri_notifications_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

src_prepare() {
    # disable tests
    sed -i 's/enable_testing()/# enable_testing()/' CMakeLists.txt  || die
    cmake_comment_add_subdirectory test

    lomiri_src_prepare
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _lomiri_notifications_variants

    lomiri_notifications_configure() {
        local mycmakeargs=(
            -DENABLE_QT6=$([[ ${MULTIBUILD_VARIANT} == qt6 ]] && echo ON || echo OFF)
        )
        lomiri_src_configure
    }
    multibuild_foreach_variant lomiri_notifications_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _lomiri_notifications_variants
    multibuild_foreach_variant cmake_src_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _lomiri_notifications_variants
    multibuild_foreach_variant lomiri_src_install
}