# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

WX_GTK_VER="3.0-gtk3"
inherit cmake desktop fcaps flag-o-matic multilib toolchain-funcs wxwidgets

MY_PV="${PV/_/-}"

DESCRIPTION="A PlayStation 2 emulator"
HOMEPAGE="https://github.com/Topaz-Reality/PCSX2-EX"
SRC_URI="https://github.com/Topaz-Reality/${PN^^}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"

RDEPEND="
	app-arch/bzip2[abi_x86_32(-)]
	app-arch/xz-utils[abi_x86_32(-)]
	dev-lang/lua:5.1[abi_x86_32(-)]
	dev-libs/libaio[abi_x86_32(-)]
	dev-libs/libxml2:2[abi_x86_32(-)]
	media-libs/alsa-lib[abi_x86_32(-)]
	media-libs/libpng:=[abi_x86_32(-)]
	media-libs/libsdl2[abi_x86_32(-),haptic,joystick,sound]
	media-libs/libsoundtouch[abi_x86_32(-)]
	media-libs/portaudio[abi_x86_32(-)]
	net-libs/libpcap[abi_x86_32(-)]
	sys-libs/zlib[abi_x86_32(-)]
	virtual/libudev[abi_x86_32(-)]
	virtual/opengl[abi_x86_32(-)]
	x11-libs/gtk+:3[abi_x86_32(-)]
	x11-libs/libICE[abi_x86_32(-)]
	x11-libs/libX11[abi_x86_32(-)]
	x11-libs/libXext[abi_x86_32(-)]
	x11-libs/wxGTK:${WX_GTK_VER}[abi_x86_32(-),X]"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${PN^^}-${MY_PV}"

FILECAPS=(
	-m 755 "CAP_NET_RAW+eip CAP_NET_ADMIN+eip" usr/bin/PCSX2
)

PATCHES=(
	"${FILESDIR}/${PN}-disable-setcap.patch"
# 	"${FILESDIR}/${PN}-fixed-unsigned-typecasts.patch"
)

pkg_setup() {
	if [[ ${MERGE_TYPE} != binary && $(tc-getCC) == *gcc* ]]; then
		# -mxsave flag is needed when GCC >= 8.2 is used
		# https://bugs.gentoo.org/685156
		if [[ $(gcc-major-version) -gt 8 || $(gcc-major-version) == 8 && $(gcc-minor-version) -ge 2 ]]; then
			append-flags -mxsave
		fi
	fi
}

src_prepare() {
	cmake_src_prepare
	sed -r -e 's@(l(auxlib|ua(lib|jit)?)\.h(pp)?)@lua5.1/\1@' -i 3rdparty/sol3/sol.hpp || die
	sed -e 's/-llua/-llua5.1/' -i CMakeLists.txt || die
	sed -e "s/PCSX2/${PN^^}/g" -i linux_various/PCSX2.desktop.in || die
	sed -e "s/@PCSX2-EX_MENU_CATEGORIES@/Game;Emulator;/" -i linux_various/PCSX2.desktop.in || die
}

src_configure() {
	multilib_toolchain_setup x86
	# Build with ld.gold fails
	# https://github.com/PCSX2/pcsx2/issues/1671
	tc-ld-disable-gold

	# pcsx2 build scripts will force CMAKE_BUILD_TYPE=Devel
	# if it something other than "Devel|Debug|Release"
	local CMAKE_BUILD_TYPE="Release"

	if use amd64; then
		# Passing correct CMAKE_TOOLCHAIN_FILE for amd64
		# https://github.com/PCSX2/pcsx2/pull/422
		local MYCMAKEARGS=(-DCMAKE_TOOLCHAIN_FILE=cmake/linux-compiler-i386-multilib.cmake)
	fi

	local mycmakeargs=(
		-DARCH_FLAG=
		-DDISABLE_BUILD_DATE=TRUE
		-DDISABLE_PCSX2_WRAPPER=TRUE
		-DDISABLE_SETCAP=TRUE
		-DEXTRA_PLUGINS=FALSE
		-DOPTIMIZATION_FLAG=
		-DPACKAGE_MODE=FALSE
		-DXDG_STD=TRUE
		-DCMAKE_LIBRARY_PATH="/usr/$(get_libdir)/${PN}"
		# -DDOC_DIR=/usr/share/doc/"${PF}"
		# -DEGL_API=FALSE
		-DGTK3_API=TRUE
		-DOPENCL_API=FALSE
		# -DPLUGIN_DIR="/usr/$(get_libdir)/${PN}"
		# wxGTK must be built against same sdl version
		-DSDL2_API=TRUE
		-DUSE_VTUNE=FALSE
	)

	setup-wxwidgets
	cmake_src_configure
}

src_install() {
	# Upstream issues:
	#  https://github.com/PCSX2/pcsx2/issues/417
	#  https://github.com/PCSX2/pcsx2/issues/3077
	QA_EXECSTACK="usr/bin/PCSX2-EX"
	QA_TEXTRELS="usr/bin/PCSX2-EX usr/lib/pcsx2-ex/*"
	dodir "/usr/lib/${PN}"
	while IFS=$'\n' read -r name; do
		cp "$name" "${D}/usr/lib/${PN}"
	done < <(find "${BUILD_DIR}" -name '*.so')
	newbin "${BUILD_DIR}/pcsx2/PCSX2" "${PN^^}"
	newicon linux_various/PCSX2.xpm "${PN^^}.xpm"
	insinto /usr/share/applications
	newins linux_various/PCSX2.desktop.in "${PN^^}.desktop"
	einstalldocs
}