# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{12..14} )

inherit gnome2-utils meson python-single-r1 xdg

DESCRIPTION="GTK4/libadwaita client for MeshCore"
HOMEPAGE="https://codeberg.org/sesivany/meshy"

SRC_URI="https://codeberg.org/sesivany/meshy/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/meshy"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+qr"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="
	${PYTHON_DEPS}
	>=gui-libs/gtk-4:4[introspection]
	>=gui-libs/libadwaita-1.8:1[introspection]
	media-libs/gstreamer:1.0[introspection]
	media-libs/libshumate[introspection]
	app-misc/geoclue[introspection]
	$(python_gen_cond_dep '
		dev-python/pygobject:3[${PYTHON_USEDEP}]
		dev-python/pycryptodome[${PYTHON_USEDEP}]
		dev-python/pyserial[${PYTHON_USEDEP}]
		dev-python/msgpack[${PYTHON_USEDEP}]
		dev-python/segno[${PYTHON_USEDEP}]
		qr? ( dev-python/pyzbar[${PYTHON_USEDEP}] )
	')
	qr? ( media-gfx/zbar )
"
BDEPEND="
	dev-libs/glib:2
	dev-libs/appstream
	dev-util/desktop-file-utils
	sys-devel/gettext
"

src_configure() {
	local emesonargs=( $(meson_use qr qr_scanner) )
	meson_src_configure
}

src_install() {
	meson_src_install
	python_optimize
}

pkg_postinst() {
	xdg_pkg_postinst
	gnome2_schemas_update
}

pkg_postrm() {
	xdg_pkg_postrm
	gnome2_schemas_update
}