# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

CHROMIUM_LANGS="
	af am ar bg bn ca cs da de el en-GB en-US es es-419 et fa fi fil fr gu he
	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr
	sv sw ta te th tr uk ur vi zh-CN zh-TW
"

inherit chromium-2 desktop xdg

DESCRIPTION="A cross-platform Chromium fork named after radioactive element No. 90"
HOMEPAGE="https://github.com/gz83/thorium"

MY_PN="thorium"

SRC_URI="
	amd64? ( https://github.com/gz83/${PN}/releases/download/M158.0.8127.41/${PN}-browser_${PV}_AVX2.deb )
"
S="${WORKDIR}"

LICENSE="GPL-3 BSD"

SLOT="0"
KEYWORDS="~amd64"
RESTRICT="bindist mirror"

RDEPEND="
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	dev-libs/nss
	gui-libs/gtk
	media-libs/alsa-lib
	media-libs/mesa
	net-print/cups
	sys-apps/dbus
	virtual/libudev
	x11-libs/cairo
"

QA_PREBUILT="*"

pkg_pretend() {
	chromium_suid_sandbox_check_kernel_config
}

src_unpack() {
	default
	unpack "${WORKDIR}"/data.tar.xz
}

src_prepare() {
	default
	# cleanup languages
	pushd "opt/chromium.org/thorium/locales" || die
	chromium_remove_language_paks
	popd || die
	mv -v "${WORKDIR}"/opt/chromium.org/thorium "${WORKDIR}"/opt/
	rm -rv "${WORKDIR}"/opt/chromium.org
	rm "${WORKDIR}"/opt/thorium/libqt5_shim.so
}

src_configure() {
	chromium_suid_sandbox_check_kernel_config
	default
}

src_install() {
	for size in {16,24,32,48,64,128,256}; do
		doicon -s "${size}" "opt/thorium/product_logo_${size}.png"
	done

	domenu "usr/share/applications/${PN}-browser.desktop"

	local DESTDIR="/opt/${PN}"

	pushd "opt/${PN}" || die

	exeinto "${DESTDIR}"
	doexe  chrome-sandbox chrome_crashpad_handler chromedriver "${PN}" "${PN}-browser" ./*.so*

	insinto "${DESTDIR}"
	doins ./*.pak ./*.bin ./*.json ./*.dat
	insopts -m0755
	doins -r locales resources

	dosym "${DESTDIR}/${PN}" "/usr/bin/${PN}"
	dosym "${DESTDIR}/${PN}-browser" "/usr/bin/${PN}-browser"
	popd || die
}