# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit meson

DESCRIPTION="Wayland compositor based on Sway"
HOMEPAGE="https://codeberg.org/raboof/volare"
SRC_URI="https://codeberg.org/raboof/volare/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm64"
IUSE="+gdk-pixbuf man +swaybar +swaynag swaybg +xwayland"

S="${WORKDIR}/${PN}"

DEPEND="
	>=dev-libs/json-c-0.13:=
	dev-libs/libpcre2:=
	>=dev-libs/wayland-1.21.0
	>=dev-libs/wayland-protocols-1.24
	>=x11-libs/libxkbcommon-1.5.0
	>=gui-libs/wlroots-0.19.0:=[slot(+)]
	media-libs/cairo
	media-libs/fontconfig
	x11-libs/pango
	dev-libs/pixman
	dev-libs/libevdev
	virtual/libudev
	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
	xwayland? (
		x11-libs/libxcb:=
		x11-libs/xcb-util-wm
	)
"
RDEPEND="
	${DEPEND}
	swaybg? ( gui-apps/swaybg )
"
BDEPEND="
	dev-util/glib-utils
	virtual/pkgconfig
	man? ( app-text/scdoc )
"

src_prepare() {
    default
    sed -i "s/wlroots_version = \['>=0.17.0', '<0.18.0'\]/wlroots_version = \['>=0.17.0', '<0.20.0'\]/" meson.build || die
    sed -i "s/dependency('wlroots'/dependency('wlroots-0.19'/" meson.build || die
    sed -i '/wlr_input_inhibitor.h/d' include/sway/input/input-manager.h || die
}

src_configure() {
	local emesonargs=(
		$(meson_feature gdk-pixbuf gdk-pixbuf)
		$(meson_feature man man-pages)
		$(meson_feature xwayland xwayland)
		-Dswaybar=$(usex swaybar true false)
		-Dswaynag=$(usex swaynag true false)
		-Dsd-bus-provider=auto
	)
	meson_src_configure
}