# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri multibuild qmake-utils

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="Mediates and multiplexes access to biometric devices"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"
SLOT="0"
IUSE="+qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 )"
RESTRICT="test mirror"

COMMON_DEPEND="
    dev-cpp/dbus-cpp
    dev-cpp/process-cpp
    dev-db/sqlite:3
    dev-libs/boost
    dev-libs/glib
    sys-apps/dbus
    sys-apps/systemd
    sys-libs/libapparmor
    qt5? (
        dev-qt/qtcore:5
        dev-qt/qtdeclarative:5
    )
    qt6? (
        dev-qt/qtbase:6
        dev-qt/qtdeclarative:6
    )
"
DEPEND="
    ${COMMON_DEPEND}
    dev-cpp/nlohmann_json
"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
    virtual/pkgconfig
"

_biometryd_variants() {
    MULTIBUILD_VARIANTS=()
    use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
    use qt6 && MULTIBUILD_VARIANTS+=( qt6 )
}

# qmlplugindump is located via PATH at configure and build time
_biometryd_qt_bindir() {
    if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
        qt6_get_bindir
    else
        qt5_get_bindir
    fi
}

src_prepare() {
    # remove test from the build
    cmake_comment_add_subdirectory tests

    sed -i 's|^libdir=.*|libdir=@CMAKE_INSTALL_FULL_LIBDIR@|' data/biometryd.pc.in || die

    lomiri_src_prepare
}

src_configure() {
    local MULTIBUILD_VARIANTS
    _biometryd_variants

    biometryd_configure() {
        local mycmakeargs=(
            -DENABLE_WERROR="OFF"
            -DUSE_SYSTEMD="ON"
        )

        if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
            mycmakeargs+=( -DENABLE_QT6="ON" )
        else
            mycmakeargs+=( -DENABLE_QT6="OFF" )
        fi

        local -x PATH="$(_biometryd_qt_bindir):${PATH}"
        lomiri_src_configure
    }
    multibuild_foreach_variant biometryd_configure
}

src_compile() {
    local MULTIBUILD_VARIANTS
    _biometryd_variants

    biometryd_compile() {
        local -x PATH="$(_biometryd_qt_bindir):${PATH}"
        cmake_src_compile
    }
    multibuild_foreach_variant biometryd_compile
}

src_install() {
    local MULTIBUILD_VARIANTS
    _biometryd_variants
    multibuild_foreach_variant lomiri_src_install
}