# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
PYTHON_COMPAT=( python3_{12..15} )

inherit autotools python-single-r1 xdg vala

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.freedesktop.org/zeitgeist/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.freedesktop.org/zeitgeist/zeitgeist/-/archive/v${PV}/${PN}-v${PV}.tar.gz
			 https://launchpad.net/ubuntu/+archive/primary/+files/${PN}_${PV}-5ubuntu6.debian.tar.xz"
fi

DESCRIPTION="Service to log activities and present to other apps"
HOMEPAGE="https://zeitgeist.freedesktop.org"


LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
IUSE="+datahub doc +downloads-monitor +fts +icu introspection nls sql-debug telepathy test"
REQUIRED_USE="${PYTHON_REQUIRED_USE} downloads-monitor? ( datahub )"
RESTRICT="!test? ( test )"

COMMON_DEPEND="
	>=dev-db/sqlite-3.7.11:3
	>=dev-libs/glib-2.43.92:2

	datahub? (
		>=dev-libs/json-glib-1.5.2
		>=x11-libs/gtk+-3.0.0:3
	)
	fts? ( >=dev-libs/xapian-1.4.17:0=[inmemory(+)] )
	icu? ( >=dev-libs/dee-1.0.2:0=[${PYTHON_SINGLE_USEDEP}] )
	introspection? ( >=dev-libs/gobject-introspection-1.30.0 )
	telepathy? ( >=net-libs/telepathy-glib-0.18.0 )

	${PYTHON_DEPS}
"
RDEPEND="${COMMON_DEPEND}
	$(python_gen_cond_dep '
		dev-python/dbus-python[${PYTHON_USEDEP}]
		dev-python/pygobject:3[${PYTHON_USEDEP}]
	')
"
DEPEND="${COMMON_DEPEND}"
BDEPEND="
	sys-devel/gettext
	virtual/pkgconfig

	doc? (
		dev-lang/vala[valadoc]
		dev-util/gtk-doc
		media-libs/raptor:2
	)

	${PYTHON_DEPS}
	$(python_gen_cond_dep 'dev-python/rdflib[${PYTHON_USEDEP}]')

	$(vala_depend)
"

S="${WORKDIR}/${PN}-v${PV}"

PATCHES=(
	"${FILESDIR}"/handle-termination-signals-in-main-loop.patch
	"${FILESDIR}"/fix-build-with-xapian-2.patch
	"${FILESDIR}"/skip-launch-events-without-launcher.patch
)

src_prepare() {
	use doc && local VALA_USE_DEPEND="valadoc"

	# Fix pre_populator.patch #
	sed -i \
		-e "s/+1,117/+1,124/" \
		-e "/rhythmbox/r ${FILESDIR}/music-clients" \
		-e '/Calculator/a +    arr.add (event_for_desktop_file ("mate-calc.desktop", ++ts));' \
		-e '/gedit/a +    arr.add (event_for_desktop_file ("pluma.desktop", ++ts));' \
		-e '/Totem/a +    arr.add (event_for_desktop_file ("vlc.desktop", ++ts));' \
		-e "/thunderbird/r ${FILESDIR}/mail-clients" \
		-e "s/rhythmbox/org.gnome.Rhythmbox3/" \
		-e "s/yelp/unity-yelp/" \
		"${WORKDIR}/debian/patches/pre_populator.patch" || die
	grep -Fq '"mate-calc.desktop"' "${WORKDIR}/debian/patches/pre_populator.patch" || die
	grep -Fq '"org.gnome.Rhythmbox3.desktop"' "${WORKDIR}/debian/patches/pre_populator.patch" || die
	grep -Fq '"unity-yelp.desktop"' "${WORKDIR}/debian/patches/pre_populator.patch" || die

	# Fix doc dir #
	sed -i "s:pkgdatadir)/doc:datadir)/doc/${PF}:" Makefile.am || die

	# Apply the Ubuntu patchset if present.
    local upatch_dir="debian/patches"
    local -a upatches
    [[ -f ${WORKDIR}/${upatch_dir}/series ]] && upatch_dir="${WORKDIR}/debian/patches"
    if [[ -f ${upatch_dir}/series ]]; then
        for x in $(grep -v \# "${upatch_dir}/series"); do
            upatches+=( "${upatch_dir}/${x}" )
        done
    fi
	if [[ -n ${upatches[@]} ]]; then
    	einfo "Processing the Ubuntu patchset (${#upatches[@]} patch$( (( ${#upatches[@]} > 1 )) && echo es)):"
        eapply "${upatches[@]}"
        einfo "Finished processing the Ubuntu patchset."
    fi

	eapply_user

	vala_setup
	export VALA_API_GEN="${VAPIGEN}"

	default

	eautoreconf
}

src_configure() {
	local myeconfargs=(
		$(use_enable doc docs)
		$(use_enable datahub)
		$(use_enable downloads-monitor)
		$(use_enable fts)
		$(use_enable introspection)
		$(use_enable nls)
		$(use_enable sql-debug explain-queries)
		$(use_enable telepathy)
	)
	econf "${myeconfargs[@]}"

	# Process translations #
	pushd po >/dev/null || die
		emake update-gmo || die
	popd >/dev/null || die
}

src_install() {
	default

	# Perform VACUUM SQLite database on startups every 10 days #
	exeinto /usr/libexec/"${PN}"
	doexe "${WORKDIR}"/debian/zeitgeist-maybe-vacuum

	# valadoc generated documentation #
	if use doc; then
		docinto html/c
		dodoc -r doc/libzeitgeist/docs_c/html/.
		docinto html/vala
		dodoc -r doc/libzeitgeist/docs_vala/.
	fi

	find "${ED}" -name '*.la' -delete || die
}

pkg_postinst() {
	xdg_pkg_postinst

	echo
	elog "In case of problems, reset ZeitGeist database:"
	elog "rm -rfv ~/.local/share/zeitgeist"
	echo
}

pkg_postrm() {
    xdg_pkg_postrm
}