# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=hatchling
PYPI_VERIFY_REPO=https://github.com/tox-dev/sphinx-autodoc-typehints
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 pypi

DESCRIPTION="Type hints support for the Sphinx autodoc extension"
HOMEPAGE="
	https://github.com/tox-dev/sphinx-autodoc-typehints/
	https://pypi.org/project/sphinx-autodoc-typehints/
"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"

RDEPEND="
	>=dev-python/sphinx-9.0.4[${PYTHON_USEDEP}]
	$(python_gen_cond_dep '
		>=dev-python/typing-extensions-4.16[${PYTHON_USEDEP}]
	' 3.{12..14})
"
# skipping optional test dep on dev-python/nptyping as that package
# is horribly broken and on its way out
BDEPEND="
	dev-python/hatch-vcs[${PYTHON_USEDEP}]
	test? (
		>=dev-python/annotated-doc-0.0.5[${PYTHON_USEDEP}]
		>=dev-python/attrs-25.4[${PYTHON_USEDEP}]
		>=dev-python/numpydoc-1.10[${PYTHON_USEDEP}]
		>=dev-python/pydantic-2[${PYTHON_USEDEP}]
		>=dev-python/sphobjinv-2.3.1[${PYTHON_USEDEP}]
		>=dev-python/typing-extensions-4.5[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# Internet
	tests/test_annotations.py::test_format_annotation
	tests/test_resolver/test_stubs.py::test_sphinx_build_stub_types_produce_crossrefs
	# requires sphinx_design
	tests/test_live_example.py
	# TODO
	tests/_resolve/backfill/stubs/test_find.py::test_stub_path_reads_the_properties_of_a_module_proxy
)