# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

UVER=+21.10.20210613.1
UREV=0ubuntu5

inherit desktop gnome2 cmake ubuntu-versionator

DESCRIPTION="Session management, status and user switching indicator for Unity7"
HOMEPAGE="https://launchpad.net/indicator-session"
SRC_URI="${SRC_URI} ${UURL}-${UREV}.diff.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64"
IUSE="+help"
RESTRICT="test"

COMMON_DEPEND="
	>=dev-libs/glib-2.43.2:2
	sys-apps/systemd[pam]
"
RDEPEND="${COMMON_DEPEND}
	dev-libs/libindicator:3
	gnome-base/dconf
	gnome-base/gnome-settings-daemon
	gnome-base/gsettings-desktop-schemas

	help? (
		gnome-extra/yelp
		gnome-extra/gnome-user-docs
		unity-base/ubuntu-docs
	)
"
DEPEND="${COMMON_DEPEND}
	sys-apps/dbus
	unity-base/unity-settings-daemon
"
BDEPEND="
	>=dev-build/cmake-extras-1.3
	dev-util/intltool
	virtual/pkgconfig
"

src_unpack() {
	ubuntu-versionator_src_unpack
}

src_prepare() {
	# Fix build with CMake 4 #
	sed -i "/cmake_minimum_required/{s/2\.8\.9/3.10/}" CMakeLists.txt || die

	if use help; then
		sed -i \
			-e 's:distro_name = g_strdup(value):distro_name = g_strdup(\"Unity\"):g' \
			src/service.c || die
		sed -i \
			-e 's:yelp:yelp help\:ubuntu-help:g' \
			src/backend-dbus/actions.c || die
	else
		sed -i \
			-e '/"indicator.help");$/{s|^|//|}' \
			src/service.c || die
	fi

	# Fix build attempting to violate sandbox #
	sed -i '/gtk-update-icon-cache/,+1 d' data/icons/CMakeLists.txt || die

	# Remove dependency on whoopsie (Ubuntu's error submission tracker) #
	sed -i 's:libwhoopsie):):g' CMakeLists.txt || die
	sed -i '/whoopsie/d' src/service.c || die

	# Disable all language files as they can be incomplete #
	#  due to being provided by Ubuntu's language-pack packages #
	cmake_comment_add_subdirectory po

	ubuntu-versionator_src_prepare
}

src_install() {
	cmake_src_install

	use help && domenu "${FILESDIR}/unity-yelp.desktop"
}