# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MAJOR="$(ver_cut 1)"
PYTHON_COMPAT=( python3_{13..15} )

inherit cmake python-any-r1 custom-cflags

DESCRIPTION="XGQT.Org utils"
HOMEPAGE="https://codeberg.org/xgqt/xgqt-cpp-app-xo-utils/"

if [[ "${PV}" == *9999* ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://codeberg.org/xgqt/xgqt-cpp-app-${PN}"
	S="${WORKDIR}/${PN}/code/source/v${MAJOR}"
else
	SRC_URI="https://codeberg.org/xgqt/xgqt-cpp-app-${PN}/archive/${PV}.tar.gz
		-> ${P}.codeberg.tar.gz"
	S="${WORKDIR}/xgqt-cpp-app-${PN}/code/source/v${MAJOR}"
	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
fi

LICENSE="MPL-2.0"
SLOT="0/${MAJOR}"
IUSE="doc exif +git nls test"
RESTRICT="!test? ( test )"

RDEPEND="
	app-arch/libarchive:=
	dev-cpp/cli11:=
	dev-libs/libyaml:=
	exif? (
		media-gfx/exiv2:=
	)
	git? (
		dev-vcs/git
	)
	nls? (
		virtual/libintl
	)
"
DEPEND="
	${RDEPEND}
"
BDEPEND="
	${PYTHON_DEPS}
	virtual/pkgconfig
	doc? (
		app-text/doxygen
	)
	nls? (
		sys-devel/gettext
	)
	test? (
		dev-cpp/gtest
	)
"

pkg_setup() {
	python-any-r1_pkg_setup
}

src_configure() {
	custom-cflags_src_configure

	local -a mycmakeargs=(
		-DCMAKE_BUILD_TYPE="${CMAKE_BUILD_TYPE}"

		-DXOU_BUILD_DOCS="$(usex doc)"
		-DXOU_BUILD_TESTING="$(usex test)"

		-DXOU_WITH_CCACHE="OFF"

		-DXOU_WITH_SYSTEM_CLI11="ON"
		-DXOU_WITH_SYSTEM_EXIV2="ON"
		-DXOU_WITH_SYSTEM_GTEST="ON"
		-DXOU_WITH_SYSTEM_YAML="ON"

		-DXOU_WITH_NLS="$(usex nls)"

		-DXOU_BUILD_BASE="ON"
		-DXOU_BUILD_AV="$(usex exif)"
		-DXOU_BUILD_GIT="$(usex git)"
	)
	cmake_src_configure
}