# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake vala xdg-utils

DESCRIPTION="CD and DVD image access library"
HOMEPAGE="https://cdemu.sourceforge.io"
SRC_URI="https://download.sourceforge.net/cdemu/libmirage/${P}.tar.xz"

LICENSE="GPL-2+"
SLOT="0/12"
KEYWORDS="~amd64 ~x86"
IUSE="crypt doc +introspection"

DEPEND="
	>=app-arch/bzip2-1:=
	>=app-arch/xz-utils-5:=
	>=dev-libs/glib-2.38:2
	>=media-libs/libchdr-0.2:=
	>=media-libs/libsamplerate-0.1:=
	>=media-libs/libsndfile-1.0:=
	virtual/zlib:=
	crypt? ( dev-libs/libgcrypt:= )
	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
"
RDEPEND="
	${DEPEND}
"
BDEPEND="
	dev-util/desktop-file-utils
	dev-util/intltool
	sys-devel/gettext
	virtual/pkgconfig
	doc? ( dev-util/gtk-doc )
	introspection? (
		>=dev-libs/gobject-introspection-1.82.0-r2
		$(vala_depend)
	)
"

DOCS=( AUTHORS README )

src_prepare() {
	cmake_src_prepare
	use introspection && vala_setup
}

src_configure() {
	local mycmakeargs=(
		-DGTKDOC_ENABLED="$(usex doc)"
		-DINTROSPECTION_ENABLED="$(usex introspection)"
		-DPOST_INSTALL_HOOKS=OFF # avoid sandbox violation, #487304
		-DLIBGCRYPT_ENABLED=$(usex crypt)
		# upstream's CMakeLists looks for unversioned "valac"/"vapigen" via
		# find_program(), which Gentoo never installs; feed it the versioned
		# binaries vala_setup resolved so libmirage.vapi actually gets built
		-DVAPI_ENABLED="$(usex introspection)"
	)
	if use introspection; then
		mycmakeargs+=(
			-DVALAC="${VALAC}"
			-DVAPIGEN="${VAPIGEN}"
		)
	fi
	cmake_src_configure
}

pkg_postinst() {
	xdg_mimeinfo_database_update
}

pkg_postrm() {
	xdg_mimeinfo_database_update
}