# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

DESCRIPTION="Customizable toolbar widget for the DeaDBeeF audio player"
HOMEPAGE="https://github.com/kravich/ddb_customizabletb"
SRC_URI="https://github.com/kravich/ddb_customizabletb/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/ddb_customizabletb-${PV}"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~arm64"
IUSE="+gtk3 gtk2"
REQUIRED_USE="|| ( gtk2 gtk3 )"

DEPEND="
	app-accessibility/at-spi2-core
	dev-libs/glib:2
	media-sound/deadbeef
	x11-libs/gdk-pixbuf:2
	gtk2? ( x11-libs/gtk+:2 )
	gtk3? ( x11-libs/gtk+:3 )
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"

src_compile() {
	local make_args=(
		CC="$(tc-getCC)"
		CFLAGS="${CFLAGS} -std=c99 -fPIC"
		LDFLAGS="${LDFLAGS}"
	)

	use gtk2 && emake "${make_args[@]}" gtk2
	use gtk3 && emake "${make_args[@]}" gtk3
}

src_install() {
	exeinto /usr/$(get_libdir)/deadbeef
	use gtk2 && doexe ddb_customizabletb_gtk2.so
	use gtk3 && doexe ddb_customizabletb_gtk3.so
}