# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{12..14} )

inherit backports check-reqs cmake db-use desktop edo python-any-r1 systemd toolchain-funcs xdg-utils

BACKPORTS=(
	6d4214925fadc36d26aa58903db5788c742e68c6:strip=doc/	# cmake: Require Qt 6 to build GUI
)

MyPV="${PN}-${PV/_}"
DESCRIPTION="Implementation of advanced blockchain features extending the Bitcoin protocol"
HOMEPAGE="https://elementsproject.org/"
BACKPORTS_BASE_URI="https://github.com/bitcoin/bitcoin/commit/"
SRC_URI="https://github.com/ElementsProject/${PN}/archive/refs/tags/${MyPV}.tar.gz
	$(backports_patch_uris)"
S="${WORKDIR}/${PN}-${MyPV}"

LICENSE="MIT"
SLOT="0"
if [[ "${PV}" != *_rc* ]] ; then
	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
fi
IUSE="+asm +berkdb +cli +daemon dbus examples external-signer gui +man +qrcode +sqlite +system-libsecp256k1 systemtap test zeromq"
RESTRICT="!test? ( test )"

REQUIRED_USE="
	dbus? ( gui )
	qrcode? ( gui )
"
RDEPEND="
	>=dev-libs/boost-1.81.0:=
	external-signer? ( !!>=dev-libs/boost-1.88 )
	>=dev-libs/libevent-2.1.12:=
	berkdb? ( >=sys-libs/db-4.8.30:$(db_ver_to_slot 4.8)=[cxx] )
	daemon? (
		acct-group/elements
		acct-user/elements
	)
	gui? (
		>=dev-qt/qtbase-6.2:6[dbus?,gui,network,widgets]
	)
	qrcode? ( >=media-gfx/qrencode-4.1.1:= )
	sqlite? ( >=dev-db/sqlite-3.38.5:= )
	system-libsecp256k1? ( >=dev-libs/libsecp256k1-zkp-0.1.0_pre20260618:=[ecdh,ellswift,extrakeys,generator,rangeproof,recovery,schnorrsig,surjectionproof,whitelist] )
	zeromq? ( >=net-libs/zeromq-4.3.4:= )
"
DEPEND="
	${RDEPEND}
	systemtap? ( >=dev-debug/systemtap-4.8 )
"
BDEPEND="
	>=dev-build/cmake-3.25
	virtual/pkgconfig
	daemon? (
		acct-group/elements
		acct-user/elements
	)
	gui? ( >=dev-qt/qttools-6.2:6[linguist] )
	test? (
		${PYTHON_DEPS}
	)
"
IDEPEND="
	gui? ( dev-util/desktop-file-utils )
"

DOCS=(
	doc/bips.md
	doc/bitcoin-conf.md
	doc/descriptors.md
	doc/files.md
	doc/i2p.md
	doc/JSON-RPC-interface.md
	doc/multisig-tutorial.md
	doc/p2p-bad-ports.md
	doc/psbt.md
	doc/reduce-memory.md
	doc/reduce-traffic.md
	doc/release-notes.md
	doc/REST-interface.md
	doc/tor.md
)

PATCHES=(
	"${FILESDIR}/29.4.1-cmake-syslibs.patch"
)

efmt() {
	: ${1:?} ; local l ; while read -r l ; do "${!#}" "${l}" ; done < <(fmt "${@:1:$#-1}")
}

pkg_pretend() {
	if ! use daemon && ! use gui && ! has_version "${CATEGORY}/${PN}[-daemon,-gui]" ; then
		efmt ewarn <<-EOF
			You are enabling neither USE="daemon" nor USE="gui". This is a valid
			configuration, but you will be unable to run an Elements node using this
			installation.
		EOF
	fi
	if use daemon && ! use cli && ! has_version "${CATEGORY}/${PN}[daemon,-cli]" ; then
		efmt ewarn <<-EOF
			You are enabling USE="daemon" but not USE="cli". This is a valid
			configuration, but you will be unable to interact with your elementsd node
			via the command line using this installation.
		EOF
	fi
	if ! use berkdb && ! use sqlite &&
		{ { use daemon && ! has_version "${CATEGORY}/${PN}[daemon,-berkdb,-sqlite]" ; } ||
		  { use gui && ! has_version "${CATEGORY}/${PN}[gui,-berkdb,-sqlite]" ; } ; }
	then
		efmt ewarn <<-EOF
			You are enabling neither USE="berkdb" nor USE="sqlite". This is a valid
			configuration, but your Elements node will be unable to open any wallets.
		EOF
	fi

	# test/functional/feature_pruning.py requires 4 GB disk space
	use test && CHECKREQS_DISK_BUILD="4G" check-reqs_pkg_pretend
}

pkg_setup() {
	if use test ; then
		CHECKREQS_DISK_BUILD="4G" check-reqs_pkg_setup
		python-any-r1_pkg_setup
	fi
}

src_prepare() {
	# https://bugs.gentoo.org/958361
	# https://github.com/google/crc32c/commit/2bbb3be42e20a0e6c0f7b39dc07dc863d9ffbc07
	sed -e '/^cmake_minimum_required(VERSION 3\.1)$/s/)$/6)/' -i src/crc32c/CMakeLists.txt || die

	# https://bugs.gentoo.org/965371
	# https://github.com/google/leveldb/issues/1289
	sed -e '/^cmake_minimum_required(VERSION 3\.9)$/s/9)$/10)/' -i src/leveldb/CMakeLists.txt || die

	backports_apply_patches
	eapply_user
	! use system-libsecp256k1 || rm -r src/secp256k1 || die
	cmake_src_prepare

	mv contrib/devtools/gen-{bitcoin,elements}-conf.sh || die
	sed -e 's/bitcoin/elements/g' \
		-i contrib/devtools/gen-elements-conf.sh || die

	mv share/examples/{bitcoin,elements}.conf || die
	sed -e 's/Bitcoin/Elements/g' -e 's/bitcoin\([^s]\)/elements\1/g' \
		-e '3a mainchainrpccookiefile=/var/lib/bitcoind/.cookie\' \
		-e 'rpccookiefile=/var/lib/elementsd/.cookie' \
		-i share/examples/elements.conf || die

	# we set BUILD_UTIL=OFF, so we can't test elements-util
	sed -ne '/^  {/{h;:0;n;H;/^  }/!b0;g;\|"exec": *"\./elements-util"|d};p' \
		-i test/util/data/bitcoin-util-test.json || die

	sed -Ee 's:^(\s*#\s*include\s+<)secp256k1/include/:\1:' \
		-i src/primitives/pak.h || die
}

src_configure() {
	local wallet ; if use berkdb || use sqlite ; then wallet=ON ; else wallet=OFF ; fi
	local mycmakeargs=(
#		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON	# https://github.com/bitcoin/bitcoin/pull/32220
		-DBUILD_SHARED_LIBS=ON
		-DENABLE_WALLET=${wallet}
		-DWITH_SQLITE=$(usex sqlite)
		-DWITH_BDB=$(usex berkdb)
		-DWITH_USDT=$(usex systemtap)
		-DBUILD_TESTS=$(usex test)
		-DBUILD_BENCH=OFF
		-DBUILD_{FOR_FUZZING,FUZZ_BINARY}=OFF
		-DWITH_QRENCODE=$(usex qrcode)
		-DWITH_CCACHE=OFF
		-DWITH_ZMQ=$(usex zeromq)
		-DENABLE_EXTERNAL_SIGNER=$(usex external-signer)
		-DBUILD_CLI=$(usex cli)
		-DBUILD_TX=ON
		-DBUILD_WALLET_TOOL=${wallet}
		-DBUILD_UTIL=OFF
		-DBUILD_DAEMON=$(usex daemon)
		-DBUILD_GUI=$(usex gui)
		-DWITH_DBUS=$(usex dbus)
		-DWITH_SYSTEM_LIBSECP256K1=$(usex system-libsecp256k1 ON \
			"OFF -DSECP256K1_ASM=$(usex asm AUTO OFF)")
	)
	cmake_src_configure
}

src_compile() {
	cmake_src_compile

	if use daemon && ! tc-is-cross-compiler ; then
		TOPDIR="${S}" BUILDDIR="${BUILD_DIR}" bash contrib/devtools/gen-elements-conf.sh || die
	fi
	sed -e 's:^#\?\(mainchainrpccookiefile=\).*$:\1/var/lib/bitcoind/.cookie:;tp' \
		-e 's:^#\?\(rpccookiefile=\).*$:\1/var/lib/elementsd/.cookie:;tp' \
		-e 's/ To use, copy this file$//p;Tp;:0;n;/save the file\.$/!b0;d;:p;p' \
		-ni share/examples/elements.conf || die
}

src_test() {
	cmake_src_test

	# --extended fails
	# https://github.com/ElementsProject/elements/issues/1296
	# https://github.com/ElementsProject/elements/issues/1297
	if use daemon ; then
		cd -- "${BUILD_DIR}" || die
		edo "${PYTHON}" test/functional/test_runner.py \
			--ansi --jobs="$(get_makeopts_jobs)" --timeout-factor="${TIMEOUT_FACTOR:-15}"
	fi
}

src_install() {
	dodoc -r doc/release-notes

	use external-signer && DOCS+=( doc/external-signer.md )
	use berkdb || use sqlite && DOCS+=( doc/managing-wallets.md )
	use systemtap && DOCS+=( doc/tracing.md )
	use zeromq && DOCS+=( doc/zmq.md )

	if use daemon ; then
		# https://bugs.gentoo.org/757102
		DOCS+=( share/rpcauth/rpcauth.py )
		docompress -x "/usr/share/doc/${PF}/rpcauth.py"
	fi

	einstalldocs
	cmake_src_install

	find "${ED}" -type f -name '*.la' -delete || die
	! use test || rm -f -- "${ED}"/usr/bin/test_{bitcoin,elements}{,-qt} || die

	if use daemon ; then
		insinto /etc/elements
		doins share/examples/elements.conf
		fowners elements:elements /etc/elements/elements.conf
		fperms 0660 /etc/elements/elements.conf

		newconfd "${FILESDIR}/elementsd.openrcconf" elementsd
		newinitd "${FILESDIR}/elementsd.openrc" elementsd
		systemd_dounit "${FILESDIR}/elementsd.service"

		keepdir /var/lib/elementsd
		fperms 0750 /var/lib/elementsd
		fowners elements:elements /var/lib/elementsd
		dosym -r {/etc/elements,/var/lib/elementsd}/elements.conf

		insinto /etc/logrotate.d
		newins "${FILESDIR}/elementsd.logrotate-r1" elementsd
	fi

	if use gui ; then
		insinto /usr/share/icons/hicolor/scalable/apps
		newins src/qt/res/src/bitcoin.svg elements.svg

		domenu "${FILESDIR}/org.elementsproject.elements-qt.desktop"
	fi

	if use examples ; then
		docinto examples
		dodoc -r contrib/{linearize,qos}
		use zeromq && dodoc -r contrib/zmq
	fi
}

pkg_postinst() {
	# we don't use xdg.eclass because it adds unconditional IDEPENDs
	if use gui ; then
		xdg_desktop_database_update
		xdg_icon_cache_update
	fi

	if use cli && use daemon ; then
		efmt -su elog <<-EOF
			To use elements-cli with the /etc/init.d/elementsd service:
			 - Add your user(s) to the 'elements' group.
			 - Symlink ~/.elements to /var/lib/elementsd.
		EOF
	fi
}

pkg_postrm() {
	if use gui ; then
		xdg_desktop_database_update
		xdg_icon_cache_update
	fi
}