# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ROCM_VERSION=${PV}

inherit cmake rocm

DESCRIPTION="Generate pseudo-random and quasi-random numbers"
HOMEPAGE="https://github.com/ROCm/rocRAND"
SRC_URI="https://github.com/ROCm/${PN}/archive/rocm-${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-rocm-${PV}"

LICENSE="MIT"
SLOT="0/$(ver_cut 1-2)"
KEYWORDS="~amd64"
IUSE="benchmark test"
REQUIRED_USE="${ROCM_REQUIRED_USE}"

RESTRICT="!test? ( test )"

# cmake/Dependencies.cmake does find_package(benchmark 1.9.1 QUIET) and, on
# failure, falls through to a FetchContent clone of github.com/google/benchmark,
# which cannot work inside portage's network sandbox. ::gentoo still ships 1.8.4
# next to the 1.9.x line, so an existing 1.8.4 install satisfied the bare atom,
# got no upgrade, and sent USE=benchmark builds down the fetch path.
# verified 2026-07-27
RDEPEND="
	dev-util/hip:${SLOT}
	benchmark? ( >=dev-cpp/benchmark-1.9.1 )
"
DEPEND="${RDEPEND}
	dev-build/rocm-cmake
	test? ( dev-cpp/gtest )"
BDEPEND="dev-build/rocm-cmake"

PATCHES=(
	"${FILESDIR}/${PN}-7.2.0-no-tests-install.patch"
)

src_configure() {
	rocm_use_clang

	export ROCM_PATH="${EPREFIX}/usr"

	local mycmakeargs=(
		-DCMAKE_SKIP_RPATH=ON
		-DAMDGPU_TARGETS="$(get_amdgpu_flags)"
		-DROCM_SYMLINK_LIBS=OFF
		-DBUILD_TEST=$(usex test ON OFF)
		-DBUILD_BENCHMARK=$(usex benchmark ON OFF)
	)

	cmake_src_configure
}

src_test() {
	check_amdgpu
	export LD_LIBRARY_PATH="${BUILD_DIR}/library"
	# uses HMM to fit tests to default <512M iGPU VRAM
	ROCRAND_USE_HMM="1" cmake_src_test -j1
}

src_install() {
	cmake_src_install

	if use benchmark; then
		cd "${BUILD_DIR}"/benchmark || die
		dobin benchmark_rocrand_*
	fi
}