# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=no
DISTUTILS_SINGLE_IMPL=1
PYTHON_COMPAT=( python3_13 )

inherit distutils-r1

MY_PN="${PN/-/_}"
DESCRIPTION="Spatially sparse convolution library (prebuilt cu126 wheel)"
HOMEPAGE="
	https://github.com/traveller59/spconv
	https://pypi.org/project/spconv-cu126/
"
# CUDA 12.6 wheel matching TRELLIS's spconv-format weights; torchsparse is
# incompatible. Bundled kernels do not link libtorch, so no torch pin is needed.
SRC_URI="
	https://files.pythonhosted.org/packages/af/fd/c52d71468849d09b333123f9d0cac27b4a3815a8faecff21ebd66d9c7b45/${MY_PN}-${PV}-cp313-cp313-manylinux_2_28_x86_64.whl
"
S="${WORKDIR}"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="-* ~amd64"
RESTRICT="bindist mirror strip"

QA_PREBUILT="usr/lib/python3.*/site-packages/spconv/*"

RDEPEND="
	~dev-python/cumm-cu126-0.7.11[${PYTHON_SINGLE_USEDEP}]
	$(python_gen_cond_dep '
		>=dev-python/pccm-0.4.16[${PYTHON_USEDEP}]
		>=dev-python/ccimport-0.4.4[${PYTHON_USEDEP}]
		>=dev-python/pybind11-2.6.0[${PYTHON_USEDEP}]
		dev-python/fire[${PYTHON_USEDEP}]
		dev-python/numpy[${PYTHON_USEDEP}]
	')
"
BDEPEND="$(python_gen_cond_dep '
	dev-python/installer[${PYTHON_USEDEP}]
')"

src_unpack() {
	cp "${DISTDIR}/${A}" "${WORKDIR}/" || die
}

src_compile() { :; }

src_install() {
	python_setup
	"${EPYTHON}" -m installer --destdir="${D}" "${WORKDIR}/${A}" || die
	python_optimize
}