# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MY_PN="${PN/%-bin/}"
inherit edo shell-completion unpacker

DESCRIPTION="Proxmox Backup Client"
HOMEPAGE="https://proxmox.com/en/products/proxmox-backup-server/overview"
SRC_URI="http://download.proxmox.com/debian/pbs-client/dists/trixie/main/binary-amd64/${MY_PN}-static_${PV}-1_amd64.deb"
S="${WORKDIR}"
LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="-* ~amd64"

QA_PREBUILT="
	opt/${MY_PN}/proxmox-backup-client
	opt/${MY_PN}/pxar
"

DOCS=( usr/share/doc/${MY_PN}-static/{changelog.Debian,copyright} )

src_unpack() {
	unpack_deb ${A}
}

src_prepare() {
	default

	# Prepare compressed documentation
	edo gunzip usr/share/doc/${MY_PN}-static/*.gz
	edo gunzip usr/share/man/man1/*.gz
}

src_install() {
	default

	# Install static binaries
	exeinto /opt/${MY_PN}
	doexe usr/bin/{proxmox-backup-client,pxar}
	dosym -r /opt/${MY_PN}/proxmox-backup-client /usr/bin/proxmox-backup-client
	dosym -r /opt/${MY_PN}/pxar /usr/bin/pxar

	# Install shell completions
	dobashcomp usr/share/bash-completion/completions/{proxmox-backup-client,pxar}
	dozshcomp usr/share/zsh/vendor-completions/_{proxmox-backup-client,pxar}

	# Install documentation
	doman usr/share/man/man1/{proxmox-backup-client,pxar}.1
}