# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..14} )

inherit distutils-r1

DESCRIPTION="Magnificent app which corrects your previous console command"
HOMEPAGE="https://github.com/nvbn/thefuck"
SRC_URI="https://github.com/nvbn/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"

RDEPEND="
	dev-python/psutil[${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]
	dev-python/decorator[${PYTHON_USEDEP}]
	dev-python/colorama[${PYTHON_USEDEP}]
	dev-python/pyte[${PYTHON_USEDEP}]
"

PATCHES=(
	"${FILESDIR}"/${P}-python-312.patch
	"${FILESDIR}"/${PN}-3.32-setuptools_82.patch
)

EPYTEST_PLUGINS=( pytest-mock mock )
distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# failing tests because of trying to access portage's home dir
	tests/test_conf.py
	tests/entrypoints/test_not_configured.py
	tests/test_utils.py::test_get_all_executables_exclude_paths
	tests/test_utils.py::TestCache
	# These tests fail with py312; #929026
	tests/test_utils.py::TestGetValidHistoryWithoutCurrent::test_get_valid_history_without_current
)