# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LOMIRI_PPA_COMMIT="0.8.0_git20260226.fb30a11-2"
inherit lomiri qmake-utils

git_commit="fb30a113f807c1687ba91742ecb643c6ad5e7b80" # personal/sunweaver/debian-upstream

SRC_URI="https://gitlab.com/ubports/development/core/qtmir/-/archive/${git_commit}/qtmir-${git_commit}.tar.gz
        ${LOMIRI_PPA_URI}"

KEYWORDS="~amd64"
DESCRIPTION="QPA plugin to make Qt a Mir server"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="LGPL-3"
SLOT="0"

S="${WORKDIR}/qtmir-${git_commit}"

DEPEND="
    dev-cpp/process-cpp
    dev-util/lttng-ust
    gui-libs/mir:0/2.25
    lomiri-base/lomiri-api
    lomiri-base/lomiri-app-launch
    lomiri-base/lomiri-url-dispatcher
    lomiri-base/gsettings-qt
    media-libs/freetype
    media-libs/harfbuzz
    media-libs/libglvnd
    dev-qt/qtsensors:5
    x11-libs/libxkbcommon
"

RDEPEND="${DEPEND}"

BDEPEND="
    >=dev-build/cmake-3.31
    dev-build/cmake-extras
    dev-build/samurai
    dev-qt/qtdeclarative:5
    dev-util/intltool
"

PATCHES=(
    "${FILESDIR}"/002-disable-werror.patch
    "${FILESDIR}"/004_fix-fontconfig-static-libs.patch
)

src_prepare() {
    # remove hard coded enabling of tests
    sed -i "/# Tests/,/endif()/d" CMakeLists.txt  || die

    # remove demos & benchmark tests
    cmake_comment_add_subdirectory demos
    cmake_comment_add_subdirectory benchmarks

    # disable not needed patches
    sed -i 's/^2003_disable-benchmarks.patch/#/' ${DEBIAN_PATCHES_S}/debian/patches/series

    lomiri_src_prepare
}

src_configure() {
    # add 'qmlplugindump' to PATH
    export PATH="$(qt5_get_bindir):${PATH}"

    local mycmakeargs=(
        -DWITH_MIR2=ON
        -DWITH_VALGRIND="OFF"
    )

    lomiri_src_configure
}