# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri qmake-utils

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="Library for exporting anonymous metrics about users"
HOMEPAGE="https://gitlab.com/ubports/development/core/${PN}"
LICENSE="GPL-3"

DEPEND="
    dev-libs/glib
    dev-util/click
    dev-qt/qtsql:5
    dev-qt/qtxmlpatterns:5
    lomiri-base/gsettings-qt
    sys-libs/libapparmor
"

RDEPEND="
    ${DEPEND}
    acct-group/usermetrics
    acct-user/usermetrics
"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

PATCHES=(
    "${FILESDIR}"/002-fix-plugin-install-dir.patch
)

src_prepare() {
    # fix 'cmake_minimum_required'
    sed -i "s/^cmake_minimum_required.*/cmake_minimum_required(VERSION 3.5)/" CMakeLists.txt || die

    # remove ctest from the build
    sed -i '/include(CTest)/d' CMakeLists.txt || die
    cmake_comment_add_subdirectory tests

    # fix cmake deprecation warning about obsolate 'add_compiler_export_flags' function
    sed -i 's/add_compiler_export_flags()/set(CMAKE_CXX_VISIBILITY_PRESET hidden)/' src/CMakeLists.txt || die

    lomiri_src_prepare
}