# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MAIN_PH=d3bd4bd53c1e397467bd5c159f84c672af79b7eb
AUX_PH=d3bd4bd53c1e397467bd5c159f84c672af79b7eb

inherit racket

DESCRIPTION="Rhombus drawing library"
HOMEPAGE="https://pkgs.racket-lang.org/package/rhombus-draw"
SRC_URI="https://github.com/racket/rhombus/archive/${MAIN_PH}.tar.gz -> ${P}.tar.gz
	https://github.com/racket/rhombus/archive/${AUX_PH}.tar.gz -> ${PN}_aux_rhombus-gui-${PV}.tar.gz"
S="${WORKDIR}/rhombus-${MAIN_PH}/rhombus-draw"

LICENSE="|| ( Apache-2.0 MIT )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

RDEPEND="dev-racket/rhombus
	dev-racket/rhombus-draw-lib
	dev-racket/rhombus-lib
	dev-racket/rhombus-scribble-lib"
BDEPEND="${RDEPEND}"
PDEPEND="dev-racket/rhombus-gui"

src_compile() {
	pushd "${WORKDIR}/rhombus-${AUX_PH}/rhombus-gui" >/dev/null || die
	raco_bare_install user rhombus-gui
	popd >/dev/null || die

	racket_src_compile
}

pkg_prerm() {
	if [[ -z "${REPLACED_BY_VERSION}" ]] && racket-where rhombus-gui ; then
		raco_remove "${RACKET_PN}" rhombus-gui
	fi
}

pkg_postinst() {
	! racket-where "${RACKET_PN}" && raco_system_install

	has_version dev-racket/rhombus-gui &&
		raco_system_setup "${RACKET_PN}" rhombus-gui
}