# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

uPDFParserHash="6060d123441a06df699eb275ae5ffdd50409b8f3"

DESCRIPTION="Free implementation of Adobe's ADEPT protocol used to add DRM on ePub/PDF files"
HOMEPAGE="https://forge.soutade.fr/soutade/libgourou"
SRC_URI="https://forge.soutade.fr/soutade/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
https://forge.soutade.fr/soutade/uPDFParser/archive/${uPDFParserHash}.tar.gz -> udfparser-${uPDFParserHash}.tar.gz
"

S="${WORKDIR}/${PN}"

LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="~amd64"

DEPEND="dev-libs/libzip
	dev-libs/openssl
	dev-libs/pugixml
	net-misc/curl"
RDEPEND="${DEPEND}"
BDEPEND=""

src_prepare() {
	default

	mkdir -p "${S}/lib/" || die
	mv "${WORKDIR}/updfparser" "${S}/lib/" || die
}

src_compile() {
	pushd lib/updfparser
	emake BUILD_STATIC=1 BUILD_SHARED=0
	popd

	emake \
		PREFIX="${EPREFIX}/usr" \
		LIBDIR="/$(get_libdir)"
}

src_install() {
	emake \
		PREFIX="${EPREFIX}/usr" \
		LIBDIR="/$(get_libdir)" \
		DESTDIR="${D}" install
}