# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

[[ "${PV}" = *9999* ]] && live=git-r3
inherit ${live}

MY_PV="v${PV}"

DESCRIPTION="General Lua libraries"
HOMEPAGE="http://github.com/lua-stdlib/lua-stdlib"
if [[ "${PV}" = *9999* ]] ; then
	EGIT_REPO_URI="https://github.com/lua-stdlib/${PN}.git"
	KEYWORDS="-*"
else
	SRC_URI="https://github.com/lua-stdlib/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

LICENSE="GPL-3"
SLOT="0"

IUSE="luajit test"

RDEPEND="!luajit? ( || ( dev-lang/lua:5.3 dev-lang/lua:5.2 dev-lang/lua:5.1 >=dev-lang/lua-5.1:0 ) )
	luajit? ( dev-lang/luajit:2 )"
DEPEND="${RDEPEND}
	test? ( >=dev-lua/specl-14.1 )
	>=dev-lua/LDoc-1.4.2
	dev-lua/slingshot
	sys-apps/grep
	sys-apps/sed"

DOCS=( "README.md" "NEWS.md" )

src_prepare() {
	rmdir slingshot || die
	ln -s "${EPREFIX}"/usr/share/slingshot . || die

	# WARNING: Order matters! Slingshot options are processed first and are ignored otherwise!
	./bootstrap --skip-rock-checks --skip-git --skip-po || die
}

src_configure() {
	local lua=lua
	use luajit && lua=luajit

	econf \
		LUA="${lua}"
}

src_test() {
	emake check
}