EAPI=4
inherit eutils gnome2-utils fdo-mime qt4-r2 games

DESCRIPTION="Multimedia interpreter for TADS text adventures"
HOMEPAGE="http://qtads.sourceforge.net"
SRC_URI="mirror://sourceforge/qtads/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

# Note that for sdl-sound, we need the "mp3", not the "mpeg" USE flag. "mpeg"
# uses the SMPEG lib for decoding, which plays some MP3s at double speed. "mp3"
# uses SDL_sound's internal MPGLIB, which doesn't have that problem. It's OK
# if both "mp3" as well as "mpeg" are enabled, because SDL_sound tries MPGLIB
# first, and only if that fails will it use SMPEG.
DEPEND="dev-qt/qtgui:4
	media-libs/libsdl[audio]
	media-libs/sdl-mixer[midi,vorbis]
	media-libs/sdl-sound[mp3]"
RDEPEND="${DEPEND}"

DOCS="AUTHORS HTML_TADS_LICENSE NEWS README"

src_configure() {
	eqmake4 qtads.pro -after CONFIG-=silent
}

src_install() {
	dogamesbin qtads
	doman qtads.6
	dodoc ${DOCS}
	newicon -s 256 qtads_256x256.png ${PN}.png
	insinto /usr/share/icons
	doins -r "icons/hicolor"
	insinto /usr/share/mime/packages
	doins "icons/qtads.xml"
	make_desktop_entry qtads QTads ${PN} Game "GenericName=TADS Multimedia Interpreter\nMimeType=application/x-tads;application/x-t3vm-image;"
	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}