# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/deja-dup/deja-dup-23.4.ebuild,v 1.1 2012/07/30 08:57:23 jlec Exp $

EAPI=4

GNOME2_LA_PUNT="yes"

inherit autotools bzr eutils gnome2

DESCRIPTION="Simple backup tool using duplicity back-end"
HOMEPAGE="https://launchpad.net/deja-dup/"
SRC_URI=""
EBZR_REPO_URI="lp:deja-dup"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="nautilus"

RESTRICT="test"

VALAC_VER=0.18

COMMON_DEPEND="
	app-crypt/libsecret[vala]
	dev-libs/glib:2
	dev-libs/libpeas
	x11-libs/gtk+:3
	x11-libs/libnotify

	app-backup/duplicity
	dev-libs/dbus-glib

	nautilus? ( gnome-base/nautilus )"
RDEPEND="${COMMON_DEPEND}
	gnome-base/gvfs[fuse]"
DEPEND="${COMMON_DEPEND}
	app-text/yelp-tools
	dev-lang/vala:${VALAC_VER}
	dev-perl/Locale-gettext
	virtual/pkgconfig
	dev-util/intltool
	sys-devel/gettext"

src_unpack() {
	bzr_src_unpack
}

EBZR_BOOTSTRAP=eautoreconf

src_prepare() {
	bzr_src_prepare
	DOCS="NEWS AUTHORS"
	G2CONF="${G2CONF}
		$(use_with nautilus)
		--without-ccpanel
		--without-unity
		--disable-schemas-compile
		--disable-static"
	export VALAC=$(type -p valac-${VALAC_VER})

	gnome2_src_prepare
}

src_install() {
	gnome2_src_install
	domenu data/deja-dup.desktop
}