# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI="1"
inherit eutils wxwidgets flag-o-matic qt4 autotools git

DESCRIPTION="Tools to create, alter, and inspect Matroska files"
HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
EGIT_REPO_URI="git://git.bunkus.org/mkvtoolnix.git"
EGIT_BOOTSTRAP="autogen.sh"

LICENSE="GPL-2"
SLOT="0"

if [[ ${PV} != *9999* ]]; then
	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
else
	KEYWORDS=""
fi

IUSE="bzip2 debug doc flac lzo qt4 wxwidgets"

RDEPEND=">=dev-libs/libebml-1.0.0
	>=media-libs/libmatroska-1.0.0
	media-libs/libogg
	media-libs/libvorbis
	dev-libs/expat
	sys-libs/zlib
	dev-libs/boost
	wxwidgets? ( x11-libs/wxGTK:2.8 )
	flac? ( media-libs/flac )
	bzip2? ( app-arch/bzip2 )
	lzo? ( dev-libs/lzo )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	dev-ruby/rake"

pkg_setup() {
	WX_GTK_VER="2.8"
	if use wxwidgets; then
		need-wxwidgets unicode
	fi
}


src_compile() {
	use wxwidgets && myconf="--with-wx-config=${WX_CONFIG}"
	econf \
		$(use_enable lzo) \
		$(use_enable bzip2 bz2) \
		$(use_enable wxwidgets) \
		$(use_enable debug) \
		$(use_with flac) \
		$(use_enable qt4 qt) \
		${myconf} \
		--with-boost-regex=boost_regex \
		--with-boost-filesystem=boost_filesystem \
		--with-boost-system=boost_system

	if [ -f Rakefile ]
		then
			rake || die "rake failed"
	fi
}

src_install() {
	DESTDIR="${D}" STRIP="true" rake install || die "rake install failed"
	dodoc AUTHORS ChangeLog README TODO || die "dodoc failed"
	doman doc/man/*.1 || die "doman failed"

	if use doc; then
		dohtml doc/guide/en/mkvmerge-gui.html || die "dohtml failed"
		docinto html/images
		dohtml doc/guide/en/images/* || die "dohtml failed"
		docinto examples
		dodoc examples/* || die "dodoc failed"
	fi
}

pkg_postinst() {
	use qt4 && elog "Qt GUI is unsupported by upstream, and may be removed
	soon."
}