# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
GCONF_DEBUG="no"

inherit vala gnome2 versionator eutils multilib toolchain-funcs

MY_PV=$(get_version_component_range 1-2)
DESCRIPTION="Open source photo manager for GNOME"
HOMEPAGE="http://www.yorba.org/shotwell/"
SRC_URI="http://www.yorba.org/download/${PN}/${MY_PV}/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+extra-plugins -vala"

RDEPEND=">=dev-libs/dbus-glib-0.80
	>=gnome-base/gconf-2.22.0
	>=dev-libs/libgee-0.5.0
	>=media-libs/gexiv2-0.2.0
	>=dev-libs/glib-2.26
	>=gnome-base/gnome-vfs-2.24.2
	>=media-libs/gstreamer-0.10.28
	>=x11-libs/gtk+-2.18.0:2
	|| ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-145[extras] )
	>=media-libs/libexif-0.6.16
	>=dev-libs/json-glib-0.7.6
	>=media-libs/libraw-0.9.0
	>=media-libs/libgphoto2-2.4.2
	>=net-libs/libsoup-2.26.0
	>=dev-libs/libxml2-2.6.32
	>=dev-db/sqlite-3.5.9:3
	>=dev-libs/libunique-1.0.0:1
	>=net-libs/webkit-gtk-1.1.5:2
	vala? ( dev-lang/vala )"
DEPEND="${RDEPEND}
	>=sys-devel/m4-1.4.13
	>=dev-lang/vala-0.11.7:0.12"

DOCS="AUTHORS MAINTAINERS NEWS README THANKS"

VALA_REQUIRED_VERSION="0.12"

pkg_setup() {
	tc-export CC
	vala_pkg_setup
}

src_configure() {

	G2CONF="${G2CONF}
		--disable-schemas-install
		--disable-desktop-update
		--disable-icon-update
		--lib=$(get_libdir)"

	use vala && G2CONF="${G2CONF} --install-headers"
	use extra-plugins || G2CONF="${G2CONF} --disable-extra-plugins-install"

	gnome2_src_configure
}

src_install() {
	# This is needed so that gnome2_gconf_savelist() works correctly.
	insinto /etc/gconf/schemas
	doins misc/shotwell.schemas

	gnome2_src_install
}