# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rapidsvn/rapidsvn-0.12.0.ebuild,v 1.4 2011/12/04 16:41:54 hwoarang Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} )

WX_GTK_VER=2.8

AUTOTOOLS_AUTORECONF=true

inherit autotools-utils fdo-mime flag-o-matic git-2 python-single-r1 versionator wxwidgets

MY_PV=$(get_version_component_range 1-2)
MY_REL="1"

DESCRIPTION="Cross-platform GUI front-end for the Subversion revision system"
HOMEPAGE="http://rapidsvn.tigris.org/"
#SRC_URI="http://www.rapidsvn.org/download/release/${MY_PV}/${P}-${MY_REL}.tar.gz"
SRC_URI=""
EGIT_REPO_URI="git://github.com/RapidSVN/RapidSVN.git"

LICENSE="GPL-2 LGPL-2.1 FDL-1.2"
SLOT="0"
KEYWORDS=""
IUSE="doc static-libs"

COMMON_DEP="
	dev-libs/apr
	dev-libs/apr-util
	dev-vcs/subversion
	x11-libs/wxGTK:2.8[X]"
DEPEND="${COMMON_DEP}
	doc? (
		dev-libs/libxslt
		app-text/docbook-sgml-utils
		app-doc/doxygen
		app-text/docbook-xsl-stylesheets )"
RDEPEND="${COMMON_DEP}"

S="${WORKDIR}"/RapidSVN

PATCHES=( "${FILESDIR}/${PN}-svncpp_link.patch" )

AUTOTOOLS_IN_SOURCE_BUILD=1

DOCS=( HACKING.txt TRANSLATIONS )

pkg_setup() {
	wxwidgets_pkg_setup
	python-single-r1_pkg_setup
}

src_prepare() {
	autotools-utils_src_prepare
}

src_configure() {
	local myeconfargs=( --with-wx-config=${WX_CONFIG} )

	if use doc; then
		myeconfargs+=( --with-manpage=yes )
	else
		myeconfargs+=(
				--without-xsltproc
				--with-manpage=no
				--without-doxygen
				--without-dot )
	fi

	append-cppflags $( "${EPREFIX}"/usr/bin/apr-1-config --cppflags )

	myeconfargs+=(
		--with-svn-lib="${EPREFIX}"/usr/$(get_libdir)
		--with-svn-include="${EPREFIX}"/usr/include
		--with-apr-config="${EPREFIX}/usr/bin/apr-1-config"
		--with-apu-config="${EPREFIX}/usr/bin/apu-1-config"
		)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	doicon rapidsvn/res/rapidsvn.ico librapidsvn/src/res/bitmaps/${PN}*.png
	make_desktop_entry rapidsvn "RapidSVN ${PV}" \
		"${EPREFIX}/usr/share/pixmaps/rapidsvn_32x32.png" \
		"RevisionControl;Development"

	use doc && dohtml "${S}"/doc/svncpp/html/*
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}