# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/fuse/fuse-2.6.0_pre2.ebuild,v 1.11 2006/06/08 12:06:18 genstef Exp $

ECVS_SERVER="fuse.cvs.sourceforge.net:/cvsroot/fuse"
ECVS_MODULE="fuse"
ECVS_AUTH="pserver"
ECVS_USER="anonymous"
if [ -z "${ECVS_BRANCH}" ]; then
        ECVS_BRANCH="HEAD"
fi

inherit cvs linux-mod eutils libtool autotools

DESCRIPTION="An interface for filesystems implemented in userspace."
HOMEPAGE="http://fuse.sourceforge.net"
SRC_URI=""
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="kernel_linux"

PDEPEND="kernel_FreeBSD? ( sys-fs/fuse4bsd )"

MODULE_NAMES="fuse(fs:${S}/kernel)"
CONFIG_CHECK="@FUSE_FS:fuse"
BUILD_PARAMS="majver=${KV_MAJOR}.${KV_MINOR}
			  fusemoduledir=${ROOT}/lib/modules/${KV_FULL}/fs"
BUILD_TARGETS="all"
ECONF_PARAMS="--with-kernel=${KV_OUT_DIR}"
FUSE_FS_ERROR="We have detected FUSE already built into the kernel.
We will continue, but we wont build the module this time."

S=${WORKDIR}/${PN}

pkg_setup() {
	use kernel_linux && linux-mod_pkg_setup
}

src_unpack() {
	cvs_src_unpack
	cd ${S}
	eautoreconf
	epatch ${FILESDIR}/fuse-fix-lazy-binding.patch
	elibtoolize
#	./makeconf.sh
}

src_compile() {
	einfo "Preparing fuse userland"
	econf --disable-kernel-module --disable-example || \
		die "econf failed for fuse userland"
	emake || die "emake failed"

	if use kernel_linux; then
		sed -i -e 's/.*depmod.*//g' ${S}/kernel/Makefile.in
		convert_to_m ${S}/kernel/Makefile.in
		linux-mod_src_compile
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	dodoc AUTHORS ChangeLog Filesystems README README-2.4 \
		README.NFS NEWS doc/how-fuse-works
	docinto example
	dodoc example/*

	if use kernel_linux; then
		linux-mod_src_install
	else
		insinto /usr/include/fuse
		doins include/fuse_kernel.h
	fi
}

pkg_postinst() {
	use kernel_linux && linux-mod_pkg_postinst
}