# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

# Reviewed-By: bathym 2006-05-12

inherit webapp depend.php depend.apache

MY_PV=${PV/_/-}-dep
DESCRIPTION="A browser-based multilingual IMAP client using AJAX"
HOMEPAGE="http://www.roundcube.net"
SRC_URI="mirror://sourceforge/${PN}mail/${PN}mail-${MY_PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE="mysql postgres sqlite ssl"

RDEPEND="dev-php/PEAR-Auth_SASL
	>=dev-php/PEAR-DB-1.7.11
	>=dev-php/PEAR-Mail_Mime-1.3.1-r1
	>=dev-php/PEAR-Net_SMTP-1.2.10
	dev-php/PEAR-Net_Socket
	virtual/httpd-basic"

need_php_httpd

S=${WORKDIR}/${PN}mail-${MY_PV}

pkg_setup() {
	local flags="crypt iconv imap pcre unicode"
	use ssl && flags="${flags} ssl"
	use spell && flags="${flags} curl socket"
	local dbflags="mysql postgres sqlite"
	if ! use mysql && ! use postgres && ! use sqlite ; then
		if ! PHPCHECKNODIE="yes" require_php_with_use ${flags} || \
			! PHPCHECKNODIE="yes" require_php_with_any_use ${dbflags} ; then
				die "Re-install ${PHP_PKG} with ${flags} and at least one of ${dbflags} in USE."
		fi
	else
		for db in ${dbflags} ; do
			use ${db} && flags="${flags} ${db}"
		done
		require_php_with_use ${flags}
	fi
	webapp_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"/config
	mv db.inc.php.dist db.inc.php
	mv main.inc.php.dist main.inc.php
}

src_install () {
	webapp_src_preinst
	dodoc CHANGELOG INSTALL README UPGRADING

	cp -R [[:lower:]]* SQL "${D}"/${MY_HTDOCSDIR}

	webapp_serverowned ${MY_HTDOCSDIR}/logs
	webapp_serverowned ${MY_HTDOCSDIR}/temp

	webapp_configfile ${MY_HTDOCSDIR}/config/{db,main}.inc.php
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_postupgrade_txt en UPGRADING
	webapp_src_install
}